Giáo trình VB6 - Chương 8: Tự tạo Object

n chịu trách nhiệm luôn cả mọi thứ vật dụng cần thiết (data) cho việc ấy nữa.Có một cách định nghĩa khác cho Object là một Object gồm có data structure và các Subs/Functions làm việc trên các data ấy. Thông thường, khi ta dùng Objects ít khi giám thị chúng, ngược lại nếu khi có sự cố gì thì ta muốn chúng báo cáo cho ta biết.Trong VB6, các Forms, Controls hay ActiveX là những Objects mà ta vẫn dùng lâu nay. Lấy thí dụ như Listbox. Một Listbox tự quản lý các items hiển thị bên trong nó. Ta biết listbox List1 đang có bao nhiêu items bằng cách hỏi List1.ListCount. Ta biết item nào vừa mới được selected bằng cách hỏi List1.ListIndex. Ta thêm một item vào listbox bằng cách gọi method AddItem của List1, ..v.v.. Nói cho đúng ra, Object là một thực thể của một Class. Nếu Listbox là một Class thì List1, List2 là các thực thể của Listbox. Cũng giống như Bà Tư Cháo Lòng và Dì Sáu Bánh Tầm là các thực thể của Class Đầu Bếp.Ngay cả một form tên frmMyForm mà ta viết trong VB6 chẳng hạn, nó cũng là một Class. Thường thường ta dùng thẳng frmMyForm như sau: 
 frmMyForm.Show
Trong trường hợp nầy thật ra frmMyForm tuy là một Class nhưng được dùng y như một Object. Chớ nếu muốn, ta có thể tạo ra hai, ba Objects của Class frmMyForm cùng một lúc như trong thí dụ sau: 
Dim firstForm As frmMyForm 
Dim secondForm As frmMyForm 
Set firstForm = New frmMyForm 
Set secondForm = New frmMyForm 
firstForm.Show 
secondForm.Show 
Trong thí dụ trên ta declare firstForm và secondForm là những Objects của Class frmMyForm. Sau đó ta làm nên (instantiate) các Objects firstForm và secondForm bằng statements Set... = New... firstForm và secondForm còn được gọi là các instances của Class frmMyForm. Class giống như cái khuôn, còn Objects giống như những cái bánh làm từ khuôn ấy. Chắc bạn đã để ý thấy trong VB6 từ dùng hai từ Class và Object lẫn lộn nhau. Đều nầy cũng không quan trọng, miễn là bạn nắm vững ý nghĩa của chúng.VB6 có yểm trợ Class mà ta có thể triển khai và instantiate các Objects của nó khi dùng. Một Class trong VB6 có chứa data riêng của nó, có những Subs và Functions mà ta có thể gọi. Ngoài ra Class còn có thể Raise Events, tức là báo cho ta biết khi chuyện gì xãy ra bên trong nó. Cũng giống như Event Click của CommandButton, khi User clicks lên button thì nó Raise Event Click để cho ta xử lý trong Sub myCommandButton_Click(), chẳng hạn. Classtrong VB6 không có hổ trợ Visual components, tức là không có chứa những controls như TextBox, Label .v.v.. Tuy nhiên, ta có thể lấy những control có sẵn từ bên ngoài rồi đưa cho Object của Class dùng. Bây giờ chúng ta hãy bắt đầu viết một Class. Bạn hãy mở một Project mới loại Standard EXE Visual Basic. Sau đó dùng Menu Command chọn Add Class Module:
Khi Add Class Module dialog hiện ra chọn Class Module và click Open.
Bạn sẽ thấy mở ra một khung trắng và Project Explorer với Properties Window. Trong Properties Window, hãy sửa Name property của Class thành clsBox như dưới đây:
Kế đó đánh vào những dòng code dưới đây, trong đó có biểu diển cách dùng Class clsBox.
Option Explicit 
Private mX As Integer 
Private mY As Integer 
Private mWidth As Integer 
Private mHeight As Integer 
Public Property Let X(ByVal vValue As Integer) 
 mX = vValue 
End Property 
Public Property Get X() As Integer 
 X = mX 
End Property 
Public Property Let Y(ByVal vValue As Integer) 
 mY = vValue 
End Property 
Public Property Get Y() As Integer 
 Y = mY 
End Property 
Public Property Let Width(ByVal vValue As Integer) 
 mWidth = vValue 
End Property 
Public Property Get Width() As Integer 
 Width = mWidth 
End Property 
Public Property Let Height(ByVal vValue As Integer) 
 mHeight = vValue 
End Property 
Public Property Get Height() As Integer 
 Height = mHeight 
End Property 
Public Sub DrawBox(Canvas As Object) 
 Canvas.Line (mX, mY)-(mX + mWidth, mY + mHeight), , B 
End Sub 
Public Sub ClearBox(Canvas As Object) 
 Canvas.Line (mX, mY)-(mX + mWidth, mY + mHeight), Canvas.BackColor, B 
End Sub 
Class clsBox có 4 Properties: X, Y, Width và Height. Ta sẽ instantiate một Box từ clsBox. Mỗi Box có tọa độ (X,Y) và kích thước chiều rộng và chiều cao (width, height) của nó. Thật ra ta có thể dùng Public statement để declare các biến X, Y, Width và Height. Nhưng ở đây ta cố ý declare chúng là Private, dưới dạng mX, mY, mWidth và mHeight. Khi ta muốn thay đổi các trị số của chúng, ta sẽ dùng cùng một cách viết code như bình thường (thí dụ: myBox.X = 80 ). Nhưng khi chương trình xử lý assignment statement ấy, nó sẽ execute một loại method (giống như Sub) gọi là Property Let X (vValue). Ta thấy ở đây vValue được assigned cho mX (i.e. mX = vValue ), cái Private variable của X. Như thế công việc nầy cũng chẳng khác gì sửa đổi một Public variable X. Tuy nhiên, ở đây ta có thể viết thêm code trong Property Let X để nó làm gì cũng được. Bạn có nhớ trong khi thiết kế một Label, mỗi lần bạn dùng Property Window để edit Font size, forcolor hay backcolor thì chẳng những các properties ấy của Label thay đổi, mà kết quả của sự thay đổi được có hiệu lực ngay lập tức, nghĩa là Label được hiển thị trở lại với trị số mới của property. Đó là vì trong method Property có cả code bảo Label redisplay.Ngược lại, khi ta dùng property X của Object myBox, không phải ta chỉ đọc trị số thôi mà còn execute cả cái method Property Get X. Nói tóm lại, Property cho ta cơ hội để execute một method mỗi khi User đọc hay viết trị số variable ấy.Thí dụ như nếu ta muốn kiểm soát để chỉ chấp nhận trị số tọa độ X mới khi nó không phải là số âm. Ta sẽ sửa Property Let X lại như sau:
Public Property Let X(ByVal vValue As Integer) 
 If (vValue >= 0) Then 
 mX = vValue 
 End If 
End Property 
Property có thể là Read Only hay Write Only. Nếu muốn một Property là Read Only thì ta không cung cấp Property Let. Nếu muốn một Property là Write Only thì ta không cung cấp Property Get. Ngoài ra nếu làm việc với Object, thay vì Data type thông thường, thì ta phải dùng Property Set, thay vì Property Let.Thí dụ ta cho clsBox một Property mới, gọi là Font dùng object của class stdFont của VB6. Trong clsBox ta declare một Private variable mFont và viết một Property Set Font như sau:
Private mFont As StdFont 
Public Property Set Font(ByVal newFont As StdFont) 
 Set mFont = newFont 
End Property 
Ta sẽ dùng property Font của myBox (thuộc Class clsBox) như sau:
' Declare an object of Class StdFont of VB6
Dim myFont As StdFont 
Set myFont = New StdFont 
myFont.Name = "Arial" 
myFont.Bold = True 
Dim myBox As clsBox 
Set myBox = New clsBox 
Set myBox.Font = myFont ' Call the Property Set method
Class clsBox có hai Public Subs, DrawBox và ClearBox. ClearBox cũng vẽ một box như DrawBox, nhưng nó dùng BackColor của màn ảnh (canvas), nên coi như xóa cái box có sẵn. Do đó, nếu muốn, bạn có thể sửa Sub DrawBox lại một chút để nhận một Optional draw color như sau:
Public Sub DrawBox(Canvas As Object, Optional fColor As Long) 
 If IsMissing(fColor) Then 
 Canvas.Line (mX, mY)-(mX + mWidth, mY + mHeight), , B 
 Else 
 Canvas.Line (mX, mY)-(mX + mWidth, mY + mHeight), fColor, B 
 End If 
End Sub 
Trong thí dụ trên, Optional parameter fColor được tested bằng function IsMissing. Nếu fColor là BackColor của canvas thì ta sẽ có hiệu quả của ClearBox.Trong form chính của chương trình dùng để test clsBox, mỗi khi ta refer đến một object thuộc class clsBox, IDE Intellisense sẽ hiển thị các Properties và Subs/Functions của clsBox như trong hình dưới đây:
Trong chương trình nầy, mỗi khi ta click nút Draw thì một Box được instantiate, cho tọa độ X,Y và kích thước Width, Height, rồi được vẽ ra ngay trên form. Chữ Me trong code nói đến chính cái form frmClass. 
Để cho chương trình thú vị hơn, khi user clicks nút Animate, ta sẽ cho một box màu đỏ chạy từ trái qua phải. Khi user clicks nút Two Boxes ta sẽ vẽ hai boxes, hộp trong màu xanh, hộp ngoài màu đỏ, và cho chúng chạy từ trái sang phải. Ở đây ta biểu diễn cho thấy mình muốn instantiate bao nhiêu boxes từ clsBox cũng được, và dĩ nhiên mỗi box có một bộ properties với giá trị riêng của nó.
Ta có thể lập trình để cho Object báo cáo program chủ của nó khi có một biến cố (Event) xãy ra bên trong Class.Ta thử declare một Event tên Draw trong clsBox, và viết code để mỗi khi Sub DrawBox executes thì Class sẽ Raise một event Draw.
Public Event Draw(X As Integer, Y As Integer) 
Public Sub DrawBox(Canvas As Object, Optional fColor As Long) 
 If IsMissing(fColor) Then 
 Canvas.Line (mX, mY)-(mX + mWidth, mY + mHeight), , B 
 Else 
 Canvas.Line (mX, mY)-(mX + mWidth, mY + mHeight), fColor, B 
 End If 
 RaiseEvent Draw(mX, mY) 
End Sub 
Bây giờ, trong frmClass thay vì chỉ declare Dim myBox as clsBox, ta sẽ declare Private WithEvents myBox as clsBox. Ngay sau đó, chữ myBox sẽ hiện ra trong danh sách các Object có hổ trợ Event của frmClass. Kế đó ta sẽ viết code để handle Event Draw của myBox, tức là ta cung cấp code cho Private Sub myBox_Draw (X as Integer, Y as Integer). Ở đây ta chỉ hiển thị một sứ điệp báo cáo một hộp vừa được vẽ ở đâu.
Khi chạy program, mỗi lần một clsBox object executes Sub DrawBox ta sẽ thấy frmClass display một message giống như dưới đây.
Nhớ rằng, ta declare một Object với WithEvents khi ta muốn handle các Events của nó. Trong thí dụ trên frmClass là chủ của myBox và nó handles Event Draw của myBox. Tương tự như vậy, ngay cả ở bên trong một Class, nếu Class ấy được giao cho một Object có thể Raise Events (thí dụ như TextBox, ListBox, Timer .v.v..), bạn cũng có thể declare Object ấy WithEvents để nó có thể handle Events của Object. Trong thí dụ dưới đây ta viết codes nầy trong một Class đã được giao cho một Textbox khi form chính gọi Sub InitObject để đưa cho Object một TextBox:
Private WithEvents mTextBox As TextBox 
Public Sub InitObject(givenTextBox As TextBox) 
 Set mTextBox = givenTextBox 
End Sub 
Private Sub mTextBox_KeyPress(KeyAscii As Integer) 
 ' Place your code here to handle this event within the Class Object
End Sub