Giáo trình VB6 - Chương 14: Dùng Control Data

es như dưới đây: 
Bạn có thể bấm các nút di chuyển Navigator Buttons để đi đến các record đầu (first), trước (previous), kế (next) và cuối (last). Mỗi lần bạn di chuyển đến một record mới là chi tiết của record ấy sẽ hiển thị. Nếu không dùng các Navigator Buttons, ta cũng có thể code để làm công tác tương đưong bằng cách gọi các Recordset methods MoveFirst, MovePrevious, MoveNext và MoveLast.Khi record cuối của Recordset đang hiển thị, nếu ta gọi method MoveLast thì property EOF (End-Of-File) của Recordset trở thành True. Tương tự như vậy, khi record thứ nhất của Recordset đang hiển thị, nếu ta gọi method MovePrevious thì property BOF (Begin-Of-File) của Recordset trở thành True. Nếu một Recordset không có chứa một record nào cả thì cả hai properties EOF và BOF đều là True. Đặc tính hiển thị dữ liệu trong các textboxex theo đúng record hiện thời (current record) được gọi là data binding hay data bound (buộc vào dữ liệu) và control TextBox hỗ trợ chức năng nầy được nói là Data Aware (biết bà con dữ liệu).Khi record đầu tiên đang hiển thị, nếu bạn edit Year Published để đổi từ 1985 thành 1983 rồi click Navigator button Next để hiển thị record thứ nhì, kế đó click Navigator button Previous để hiển thị lại record đầu tiên thì bạn sẽ thấy là field Year Published của record đầu tiên đã thật sự được thay đổi (updated) thành 1983.Điều nầy có nghĩa rằng khi Data1 navigates từ record nầy đến record khác thì nếu record nầy đã có sự thay đổi vì user edited, nó lưu trữ sự thay đổi đó trước khi di chuyển. Chưa chắc là bạn muốn điều nầy, do đó, nếu bạn không muốn user tình cờ edit một record thì bạn có thể set property Locked của các textboxes ấy thành True để user không thể edit các textboxes như trong hình dưới đây: Chỉ định vị trí Database lúc chạy chương trình
Cách chỉ định tên DatabaseName trong giai đoạn thiết kế (at design time) ta đã dùng trước đây tuy tiện lợi nhưng hơi nguy hiểm, vì khi ta cài chương trình nầy lên computer của khách, chưa chắc file database ấy nằm trong một folder có cùng tên. Thí dụ trên computer mình thì database nằm trong folder E:\Program Files\Microsoft Visual Studio\VB98, nhưng trên computer của khách thì database nằm trong folder C:\VB6\DataControl chẳng hạn. Do đó, khi chương trình khởi động ta nên xác định lại vị trí của database. Giả dụ ta muốn để database trong cùng một folder với chương trình đang chạy, ta có thể dùng property Path của Application Object App như sau: 
Dim AppFolder As String 
Private Sub Form_Load() 
 ' Fetch Folder where this program EXE resides
 AppFolder = App.Path 
 ' make sure it ends with a back slash
 If Right(AppFolder, 1) "\" Then AppFolder = AppFolder & "\" 
 ' Assign Full path database filename to Data1
 Data1.DatabaseName = AppFolder & "BIBLIO.MDB" 
End Sub 
Với cách code nói trên ta sẽ đảm bảo chương trình tìm thấy file database đúng chỗ, không cần biết người ta cài chương trình bạn ở đâu trong hard disk của computer khách.Nếu bạn đang học VB6 từ xa, khi nộp bài database cho giám thị VB6 mà bạn hardcode (viết chết cứng) vị trí của file database trong lúc thiết kế thì giám thị (tutor) cũng gặp cùng sự khó khăn nầy vì chưa chắc giám thị sẽ chứa database trong một folder có cùng tên như trong harddisk của bạn. 
Thêm bớt các Records
Chương trình trên dùng cũng tạm đựợc, nhưng nó không cho ta phương tiện để thêm (add), bớt (delete) các records. Bây giờ bạn hãy để vào Form 5 buttons tên: cmdEdit, cmdNew, cmdDelete, cmdUpdate và cmdCancel.Mặc dầu bạn không thấy, nhưng thật ra Control Data Data1 có một property Recordset và khi ta dùng Navigator buttons là di chuyển từ record nầy đến record khác trong Recordset ấy. Ta có thể nói đến nó bằng Notation (cách viết) Data1.Recordset, và mỗi lần muốn lấy Recordset mới nhất từ database ta dùng method Refresh như Data1.Recordset.Refresh.Lúc chuơng trình mới khởi động, user đang xem (browsing) các records thì hai buttons Update và Cancel không cần phải làm việc. Do đó ta sẽ nhân tiện Lock (khóa) các textboxes và disable (làm cho bất lực) hai buttons nầy vì không cần dùng chúng.Trong Sub SetControls dưới đây, ta dùng một parameter gọi là Editing với trị số False hay True tùy theo user đang Browse hay Edit, ta gọi là Browse mode và Edit mode. Trong Edit mode, các Textboxes được unlocked (mở khóa) và các nút cmdNew, cmdDelete và cmdEdit trở nên bất lực: 
Sub SetControls(ByVal Editing As Boolean) 
 ' Lock/Unlock textboxes
 txtTitle.Locked = Not Editing 
 txtYearPublished.Locked = Not Editing 
 txtISBN.Locked = Not Editing 
 txtPublisherID.Locked = Not Editing 
 ' Enable/Disable buttons
 CmdUpdate.Enabled = Editing 
 CmdCancel.Enabled = Editing 
 CmdDelete.Enabled = Not Editing 
 cmdNew.Enabled = Not Editing 
 CmdEdit.Enabled = Not Editing 
End Sub 
Trong Browse mode, Form có dạng như sau: 
Sub SetControls được gọi trong Sub Form_Load khi chương trình khởi động và trong Sub CmdEdit khi user click nút Edit như sau: 
Private Sub Form_Load() 
 ' Fetch Folder where this program EXE resides
 AppFolder = App.Path 
 ' make sure it ends with a back slash
 If Right(AppFolder, 1) "\" Then AppFolder = AppFolder & "\" 
 ' Assign Full path database filename to Data1
 Data1.DatabaseName = AppFolder & "BIBLIO.MDB" 
 ' Place controls in Browse Mode
 SetControls (False) 
End Sub 
Private Sub CmdEdit_Click() 
 ' Place controls in Edit Mode
 SetControls (True) 
End Sub 
Khi ta Delete một record trong recordset, vị trí của record hiện tại (current record) vẫn không thay đổi. Do đó, sau khi delete một record ta phải MoveNext. Khổ nổi, nếu ta vừa delete record cuối của Recordset thì sau khi MoveNext, property EOF của Recordset sẽ thành True. Thành ra ta phải kiểm tra điều đó, nếu đúng vậy thì lại phải MoveLast để hiển thị record cuối của Recordset như trong code của Sub cmdDelete_Click dưới đây: 
Private Sub CmdDelete_Click() 
 On Error GoTo DeleteErr 
 With Data1.Recordset 
 ' Delete new record
 .Delete 
 ' Move to next record
 .MoveNext 
 If .EOF Then .MoveLast 
 Exit Sub 
 End With 
DeleteErr: 
 MsgBox Err.Description 
 Exit Sub 
End Sub 
Trong lúc code, ta Update (cập nhật hóa) một record trong Recordset bằng method Update. Nhưng ta chỉ có thể gọi method Update của một Recordset khi Recordset đang ở trong Edit hay AddNew mode. Ta đặt một Recordset vào Edit mode bằng cách gọi method Edit của Recordset, thí dụ như Data1.Recordset.Edit. Tương tự như vậy, ta đặt một Recordset vào AddNew mode bằng cách gọi method AddNew của Recordset, thí dụ như Data1.Recordset.AddNew. 
Private Sub cmdNew_Click() 
 ' Place Recordset into Recordset AddNew mode
 Data1.Recordset.AddNew 
 ' Place controls in Edit Mode
 SetControls (True) 
End Sub 
Sau khi Recordset gọi method Update thì Recordset ấy ra khỏi AddNew hay Edit modes. Ta cũng có thể tự thoát ra khỏi AddNew hay Edit modes, hay nói cho đúng hơn là hủy bỏ mọi pending (đang chờ đợi) Update bằng cách gọi method CancelUpdate, thí dụ như Data1.Recordset.CancelUpdate.Dùng DataBound Combo
Trong chương trình hiện tại ta chỉ hiển thị lý lịch nhà xuất bản (PubID) của Title, chớ không có thêm chi tiết. Phải chi mặc dầu chương trình lưu trữ PubID, nhưng hiển thị được Company Name của nhà xuất bản cho ta làm việc để khỏi phải nhớ các con số thì hay quá. Ta có thể thực hiện điều đó bằng cách dùng Control DBCombo (Data Bound Combo). Bạn hãy dùng IDE Menu Command Project | Components... để chọn Microsoft Data Bound List Controls 6.0 rồi click Apply. Kế đó, thêm một DBCombo tên DBCombo1 vào Form. Vì ta cần một Recordset khác để cung cấp Table Publisher cho DBCombo1, nên bạn hãy thêm một control Data thứ nhì tên Data2 vào Form. Cho Data2, hãy set property DatabaseName thành E:\Program Files\Microsoft Visual Studio\VB98\BIBLIO.MDB và property RecordSource thành Publishers. Để không cho người ta thấy hình Data2 lúc run-time, bạn hãy set property Visible nó thành False. Cái mục đích của chúng ta khi dùng DBCombo1 là hiển thị Company Name của nhà xuất bản, nhưng đằng sau lưng thì không có gì thay đổi, tức là ta vẫn làm việc với PubID cho các record Title của Data1. Khi user click lên DBCombo1 để chọn một nhà xuất bản, thì ta theo Company Name đó mà chứa PubID tương ứng trong record Title của Data1. Do đó có nhiều thứ ta phải sắp đặt cho DBCombo1 như sau:
Property
Value
Chú thích
RowSource
Data2
Đây là datasource của chính DBCombo1. Nó cung cấp table Publishers.
Listfield
Company Name
Khi RowSource phía trên đã được chọn rồi, Combo của property Listfield nầy sẽ hiển thị các fields của table Publishers.  Company Name là field của RowSource mà ta muốn hiển thị trên DBCombo1.
DataSource
Data1
Đây là datasource của record mà ta muốn. edit, tức là record của table Titles
Datafield
PubID
Field (của record Title) sẽ được thay đổi.
BoundColumn
PubID
Field trong RowSource (table Publishers) tương ứng với item user chọn trong DBCombo1 (Company Name).
Khi trong Edit mode user chọn một Company Name khác trong DBCombo1 rồi click nút Update bạn sẽ thấy Textbox txtPublisherID cũng đổi theo và hiển thị con số lý lịch PubID mới. Nếu trước khi Update bạn muốn thấy PubID mới hiển thị trong Textbox txtPublisherID thì bạn có thể dùng Event Click của DBCombo1 như sau: 
Private Sub DBCombo1_Click(Area As Integer) 
 ' Display new PuBID
 txtPublisherID.Text = DBCombo1.BoundText 
End Sub 
Property BoundText của DBCombo1 là trị số của BoundColumn mà ta có thể truy cập (viết hay đọc) được. Thí dụ như bạn muốn mỗi khi thêm một record Title mới thì default PubID là 324, tức là Company Name= "GLOBAL ENGINEERING". Bạn có thể assign trị số 324 vào property BoundText của DBCombo1 trong Sub cmdNew_Click như sau: 
Private Sub cmdNew_Click() 
 ' Place Recordset into Recordset AddNew mode
 Data1.Recordset.AddNew 
 ' Default Publisher is "GLOBAL ENGINEERING", i.e. PubID=324
 DBCombo1.BoundText = 324 
 ' Place controls in Edit Mode
 SetControls (True) 
End Sub 
Trong bài tới ta sẽ học thêm về cách coding để dùng Recordset trong kỹ thuật DAO.